Originally, the language was called REX, short for Reformed Executor, but an extra "X" was added to avoid confusion with other products. The name was originally all uppercase because that was the only way to represent it in mainframe code at the time. Both editions of Mike Cowlishaw's first book on the language use all-caps, REXX, although the cover graphic uses mixed case. His book on NetRexx uses mixed case but all caps in the cover graphic with large and small caps, NETREXX. An expansion that matches the abbreviation, REstructured eXtended eXecutor, was used for the system product in 1984.^[12] The name Rexx (mixed case) is used in this article, and is commonly used elsewhere.

Objective and subjective attributes of Rexx include:

• Simple syntax
• Ability to route commands to multiple environments
• Ability to support functions, procedures and commands associated with a specific invoking environment.
• Built-in stack with the ability to interoperate with the host stack if there is one
• Small instruction set
• Free-form syntax; indentation is optional but can help readability
• Case-insensitive tokens, including variable names
• Character string basis
• Dynamic data typing; no declarations
• No reserved keywords, except in local context^[b]
• No include file facility
• Arbitrary-precision arithmetic
• Decimal arithmetic, floating-point
• Rich selection of built-in functions, especially string and word processing
• Automatic storage management
• Crash protection
• Content addressable data structures
• Associative array
• Straightforward access to system commands and facilities
• Simple error-handling, and built-in tracing and debugger
• Few artificial limitations
• Simplified I/O facilities
• Unconventional operators
• Only partly supports Unix style command line parameters, except specific implementations
• Provides no basic terminal control as part of the language, except specific implementations
• Provides no generic way to include functions and subroutines from external libraries, except specific implementations

Some claim that Rexx is a relatively simple language. With only 23 instructions (such as call, parse, and select), it has a relatively small instruction set. Rexx has limited punctuation and formatting requirements. Rexx has only one data type, the character string. Some claim that such simplicities make Rexx relatively easy to debug.

Some claim that Rexx code looks similar to PL/I code, but has fewer notations. With fewer notations, it tends to be is harder to parse via a translator, but is easier to write. Simplifying coding was intentional as noted by the Rexx design goal of the principle of least astonishment.^[12]

On his own time, Mike Cowlishaw developed the language and an interpreter for it in assembly language between 20 March 1979 and mid-1982 with the intent to replace the languages EXEC and EXEC 2.^[6] Mike also intended Rexx to be a simplified and easier to learn version of PL/I, but some claim that Rexx has problematic differences from PL/I.

Rexx was first described in public at the SHARE 56 conference in Houston, Texas, in 1981,^[13] where customer reaction, championed by Ted Johnston of SLAC, led to it being shipped as an IBM product in 1982.

Over the years IBM included Rexx in almost all of its operating systems (VM/CMS, MVS TSO/E, IBM OS/400, VSE/ESA, MUSIC/SP, AIX, PC DOS, and OS/2), and has made versions available for Novell NetWare, Windows, Java, and Linux.

The first non-IBM version was written for PC DOS by Charles Daney in 1984/5^[7] and marketed by the Mansfield Software Group (founded by Kevin J. Kearney in 1986).^[6] The first Rexx compiler appeared in 1987, written for CMS by Lundin and Woodruff.^[14] Other versions have also been developed for Atari, AmigaOS, Unix (many variants), Solaris, DEC, Windows, Windows CE, Pocket PC, DOS, Palm OS, QNX, OS/2, Linux, BeOS, EPOC32/Symbian, AtheOS, OpenVMS,^[15]: 309 Apple Macintosh, and Mac OS X.^[16]

ARexx, a Rexx interpreter for Amiga, was included with AmigaOS 2 onwards and was popular for scripting and application control. Many Amiga applications have an "ARexx port" which allows control of the application via a Rexx script. Notably, a Rexx script can switch between Rexx ports to control multiple applications.

In 1990, Cathie Dager of SLAC organized the first independent Rexx symposium, which led to the forming of the Rexx Language Association. Symposia are held annually.

In 1992, the two most widely used open-source ports appeared: Ian Collier's REXX/imc for Unix and Anders Christensen's Regina^[5] (later adopted by Mark Hessling) for Windows and Unix. BRexx was developed by Vasilis N Vlachoudis, a nuclear scientist at CERN. It runs on a range of operating systems, including Unix, Linux, BSD, macOS and Windows. Its small size means it can run on an Android mobile phone. BRexx/370 is a version that runs on IBM mainframes.^{[15]: 359–383 [17]}

OS/2 has a visual development system from Watcom VX-REXX. Another dialect was VisPro REXX from Hockware.

Portable Rexx by Kilowatt and Personal Rexx by Quercus are two Rexx interpreters designed for DOS and can be run under Windows as well using a command prompt. Since the mid-1990s, two newer variants of Rexx have appeared:

• NetRexx: compiles to Java byte-code via Java source code; this has no reserved keywords at all, and uses the Java object model, and is therefore not generally upwards-compatible with 'classic' Rexx.
• Object REXX: an object-oriented generally upwards-compatible version of Rexx.

In 1996 the American National Standards Institute (ANSI) published a standard for Rexx: ANSI X3.274–1996 "Information Technology – Programming Language REXX".^[c] More than two dozen books on Rexx have been published since 1985.

Rexx marked its 25th anniversary on 20 March 2004, which was celebrated at the Rexx Language Association's 15th International REXX Symposium in Böblingen, Germany, in May 2004.

On October 12, 2004, IBM announced their plan to release their Object REXX implementation's sources under the Common Public License. Recent releases of Object REXX contain an ActiveX Windows Scripting Host (WSH) scripting engine implementing this version of the Rexx language.

On February 22, 2005, the first public release of Open Object Rexx (ooRexx) was announced. This product contains a WSH scripting engine which allows for programming of the Windows operating system and applications with Rexx in the same fashion in which Visual Basic and JScript are implemented by the default WSH installation and Perl, Tcl, Python third-party scripting engines.

In January 2018 the TIOBE index listed Rexx at position 30.^[19] Since 2018 it has been either outside the top 50, or, more frequently, outside the top 100.

In 2019, the 30th Rexx Language Association Symposium marked the 40th anniversary of Rexx. The symposium was held in Hursley, England, where Rexx was first designed and implemented.^[20]

• RexxUtil – a package of file and directory functions, windowed I/O, and functions to access system services such as WAIT and POST – is available for most Rexx environments.^[21][22][23]
• Rexx/Tk – a toolkit for graphics to be used in Rexx programmes in the same fashion as Tcl/Tk – is widely available.
• RexxEd – an integrated development environment (IDE) for Rexx – was developed for Windows.^[15]: 390
• RxSock for network communication as well as other add-ons to and implementations of Regina Rexx have been developed, and a Rexx interpreter for the Windows command line is supplied in most resource kits for various versions of Windows and works in DOS as well.

A Rexx host environment is a named interface for sending commands to an, e.g., application, operating system, subsystem. The Rexx interpreter initially has a list of known environments; the first in the list is known as the default environment. A Rexx script use the ADDRESS statement to change the default environment and may also use it to send a single command to a specific environment without changing the default environment.

This section contains instructions or advice. Wikipedia is not a guidebook; please help rewrite such content to be encyclopedic or move it to Wikiversity, Wikibooks, or Wikivoyage. (December 2012)

Rexx has three instruction types^[24]: 31

• Assignments – Single clause of the form symbol=expression, assigns a value to a variable; e.g. count=count+1, would add 1 to value in variable "count".
• Keyword instructions – The keyword is the first word of the instruction; e.g. say "Message", would print the word 'Message'.
• Commands – an expression that the interpreter evaluates and passes as a command to the default environment; e.g. "sleep 10" would cause a Unix-like host environment to produce a ten seconds delay.

The address instruction has three roles:

• An address instruction with no operand interchanges the first two host environments; normally this reinstate the previous default environment.
• An address instruction with only an environment moves it to the beginning of the list, making it the default environment.
• An address instruction with an environment and an expression passes the value of the expression as a command to the specified environment.

The ANSI standard added options for redirecting the input and output of commands.

The language provides do groups for two purposes:

• To treat a group of instructions within an if or select statement as a unit for purposes of flow control.
• For loop control, similar to many other languages. A single do group may optionally contain repetitor phrases, conditional phrases, or both, with termination whenever any of them is satisfied.

A do group begins with do and ends with end. A single group may serve both purposes. In the related ooRexx and NetRexx, there is both a do and a loop keyword, with almost identical semantics; they differ in that a simple do is equivalent to do 1 while a simple loop is equivalent to loop forever.

An iteration of a do group may be terminated with an iterate statement and the entire group may be terminated with a leave statement.

Although it is valid anywhere, a simple do is specifically useful inside conditional statements:

if foo=bar
then
  do
    i=1;j=3
  end
else
  do
    i=2;j=4
  end

The language supports testing a condition either before (do while) or after (do until) executing a group of code via syntax:

do while [condition]
  [instructions]
end

do until [condition]
  [instructions]
end

The language permits counted loops, where an expression is computed at the start of the loop and the instructions within the loop are executed that many times:

do expression
  [instructions]
end

A loop can increment a variable and stop when a limit is reached.

do index=start [to limit] [by increment] [for count]
  [instructions]
end

The increment value is 1 if the by clause is omitted. The loop continues forever if the limit to clause is omitted, unless terminated earlier by another clause or by a leave statement.

The language supports an unconditional loop via forever that continues until the loop is terminated or the program is terminated.

do forever
  [instructions]
end

Repetitive elements and conditional phrases can be combined in the same loop;^[24]: 50 e.g.:

do i=1 while i<=3; say i; end

do index=start [to limit] [by increment] [for count] [while condition]
  [instructions]
end

do expression [until condition]
  [instructions]
end

The language provides for conditional execution via if, then and else for a group delimited by do and end.

if [condition] then
  do
  [instructions]
  end
else
  do
  [instructions]
  end

For a single instruction, do and end can be omitted.

if [condition] then
  [instruction]
else
  [instruction]

The language provides multiple condition branching via select which derives from the SELECT; form of the PL/I SELECT statement .^[d] Like similar constructs in other dynamic languages, Rexx's when clauses specify full conditions – not equality tests of a single value for the statement as some languages do. In that, they are more like cascading if-then-else code than like the C or Java switch statement.

select
  when [condition] then
    [instruction or nop]
  when [condition] then
    do
    [instructions or nop]
    end
  otherwise
    [instructions or nop]
end

The nop instruction is required if no action is associated with a when condition.

The otherwise clause is optional. If omitted and no when conditions are met, then the syntax condition is raised.

Variables are typeless and initially are evaluated as their names in upper case. Thus a variable's type can vary with its use in the program:

say hello /* => HELLO */
hello = 25
say hello /* => 25 */
hello = "say 5 + 3"
say hello /* => say 5 + 3 */
interpret hello /* => 8 */
drop hello
say hello /* => HELLO */

If no novalue condition handler is configured, then an undefined variable evaluates to its name, in upper case. The built-in function SYMBOL returns "VAR" for a defined variable and does not trigger novalue even if not defined. The VALUE function gets the value of a variable without triggering a novalue condition, but its main purpose is to read and set environment variables, similar to POSIX getenv and putenv.

The language provides the compound variable construct which supports adding fields (called tails) to a variable (called a stem in this context) to support data structures such as lists, arrays, n-dimensional arrays, sparse or dense arrays, balanced or unbalanced trees and records.

The language does not provide special support for numeric array indexing like many other languages do. Instead, a compound variable with numeric tails produce a similar effect.^[25]

The following code defines variables stem.1 = 9, stem.2 = 8, stem.3 = 7...

do i = 1 to 10
  stem.i = 10 - i
end

Unlike a typical array, a tail (index) need not identify (be named) an integer value. For example, the following code is valid:

i = 'Monday'
stem.i = 2

A default value can be assigned to a stem via . but no tail.

stem. = 'Unknown'
stem.1 = 'USA'
stem.44 = 'UK'
stem.33 = 'France'

In this case stem.3, for example, evaluates to the default value, 'Unknown'.

The whole stem (including any default value) can be erased with the drop statement.

drop stem.

By convention (not part of the language) the compound stem.0 is often used to keep track of how many items are in a stem, for example a procedure to add a word to a list might be coded like this:

add_word: procedure expose dictionary.
  parse arg w
  n = dictionary.0 + 1
  dictionary.n = w
  dictionary.0 = n
return

A stem can have multiple tails. For example:

m = 'July'
d = 15
y = 2005
day.y.m.d = 'Friday'

Multiple numerical tail elements can be used to provide the effect of a multi-dimensional array.

Features similar to the compound variable are found in other languages including associative arrays in AWK, hashes in Perl and hash tables in Java, dynamic objects in JavaScript. Most of these languages provide a mechanism to iterate over the keys (tails) of such a construct, but this is lacking in classic Rexx. Instead, it is necessary to store additional information. For example, the following procedure might be used to count each occurrence of a word.

add_word: procedure expose count. word_list
  parse arg w .
  count.w = count.w + 1 /* assume count. has been set to 0 */
  if count.w = 1 then word_list = word_list w
return

and then later:

do i = 1 to words(word_list)
  w = word(word_list,i)
  say w count.w
end

More recent Rexx variants, including Object REXX and ooRexx, provide a construct to iterate over the tails of a stem.

do i over stem.
  say i '-->' stem.i
end

The parse instruction provides string-handling via syntax:

parse [upper] origin [template]

If upper is included then the input is converted to upper case before parsing.

origin describes the input as one of the following:

• arg – arguments, at top level tail of command line
• linein – standard input, e.g. keyboard
• pull – Rexx data queue or standard input
• source – info on how program was executed
• value expression with – with indicates the end of the expression
• var – a variable
• version – version/release number

template can be a combination of variables, literal delimiters, and column number delimiters.

Using a list of variables as template:

myVar = "John Smith"
parse var myVar firstName lastName
say "First name is:" firstName
say "Last name is:" lastName

displays:

First name is: John
Last name is: Smith

Using column number delimiters:

myVar = "(202) 123-1234"
parse var MyVar 2 AreaCode 5 7 SubNumber
say "Area code is:" AreaCode
say "Subscriber number is:" SubNumber

displays:

Area code is: 202
Subscriber number is: 123-1234

The interpret instruction evaluates its argument as a Rexx statement allowing for evaluation of code formatted at runtime. Uses include passing a function as a parameter, arbitrary precision arithmetic, use of the parse statement with programmatic templates, stemmed arrays, and sparse arrays.^[how?] The following example displays 16 and exits.

X = 'square'
interpret 'say' X || '(4) ; exit'
SQUARE: return arg(1)**2

The Valour software package relied upon Rexx's interpretive ability to implement an OOP environment.^{[citation needed]} Another use was found in an unreleased Westinghouse product called Time Machine that was able to fully recover following an otherwise fatal error.^{[citation needed]}

say digits() fuzz() form() /* => 9 0 SCIENTIFIC */
say 999999999+1 /* => 1.000000000E+9 */
numeric digits 10 /* only limited by available memory */
say 999999999+1 /* => 1000000000 */

say 0.9999999999=1 /* => 0 (false) */
numeric fuzz 3
say 0.99999999=1 /* => 1 (true) */
say 0.99999999==1 /* => 0 (false) */

say 100*123456789 /* => 1.23456789E+10 */
numeric form engineering
say 100*123456789 /* => 12.34567890E+9 */

say 53 // 7   /* => 4   (rest of division)*/

Calculation of the value √2:

numeric digits 50
n=2; r=1
do forever /* Newton's method */
  rr=(n/r+r)/2
  if r=rr then leave
  r=rr
end
say "SqRt" n "=" r

Output: SqRt 2 = 1.414213562373095048801688724209698078569671875377

Calculation of the value e:

numeric digits 50
e=2.5; f=0.5
do n=3
  f=f/n
  ee=e+f
  if e=ee then leave
  e=ee
end
say "e =" e

Output: e = 2.7182818284590452353602874713526624977572470936998

The signal instruction configures the runtime to run custom code to handle a system condition if triggered. Conditions include:

• error – Positive return code from a system command
• failure – Negative return code from a system command (e.g. command doesn't exist)
• halt – Abnormal termination
• novalue – A variable name was used but the variable is not defined
• notready – Input or output error (e.g. read attempts beyond end of file)
• syntax – Invalid program syntax, or some other error condition
• lostdigits – Significant digits were lost (ANSI Rexx, not in TRL second edition)

The following fragment prints a message when the user terminates (halts) it:

signal on halt;
do a = 1
  say a
  do 100000 /* a delay */
  end
end
halt:
say "The program was stopped by the user"
exit

Since Rexx version 4, a handler can be named. In the following example, the handler ChangeCodePage.Trap is configured to handle a syntax condition.

ChangeCodePage: procedure
  signal on syntax name ChangeCodePage.Trap
return SysQueryProcessCodePage()

ChangeCodePage.Trap: return 1004

When a condition is handled (as configured via signal on), the condition can be analyzed via RC which indicates the last error code and SIGL which indicates the line number of the code that triggered the condition.

• ISPF
• XEDIT
• Comparison of computer shells
• Comparison of programming languages